RoboBuggy

/*

 * @file RCbuggyMega

 * @brief Receives data from XBee, and uses this data to control the buggy. 

 *

 * Pinout circuit:

 *   Serial1: Used for XBee

 *     RX is digital pin 2 (connect to TX of XBee)

 *     TX is digital pin 3 (connect to RX of XBee)

 *

 *   Serial: Used for Programming/Debugging

 *     Connect for debugging. 

 *  

 */

#include <Servo.h> 

Servo myservo;  // create servo object to control a servo 

#define XBEE_BAUD 9600

#define DEBUG_BAUD 9600

#define PIN_LED_XBEE_INDICATOR 4

#define PIN_LED_BRAKE_DEPLOYED 5

// comes on after two seconds of lost connection

#define PIN_LED_LOSS_CONNECTION 12 

#define PIN_BRAKE_DEPLOY_OUT 8

#define PIN_SERVO_OUT 9

// Default value for the wheel. 

#define SERVO_WHEEL_DEFAULT 133

#define PIN_HALL_EFFECT_IN 10

// Packet-sending variables

unsigned long timer = 0L;

char data;

String message;

char intbuf[32];

// Buggy variables

int brake = 0;

int steeringAngle = 135;

int pingPong = 1;

// String parsing variables

int startfound = 0;

int midfound = 0;

int endfound = 1;

void setup()  {

  // Initialize debug serial and xbee serial. 

  Serial.begin(DEBUG_BAUD);

  Serial1.begin(XBEE_BAUD);

  pinMode(PIN_LED_XBEE_INDICATOR, OUTPUT);

  pinMode(PIN_LED_BRAKE_DEPLOYED, OUTPUT);

  pinMode(PIN_BRAKE_DEPLOY_OUT, OUTPUT);

  myservo.attach(PIN_SERVO_OUT);  // attaches the servo on pin 9 to the servo object 

  myservo.write(133);

}

void loop()  {

  // receive and parse message from xbee

  if(Serial1.available() > 0) { 

    timer = millis();

    // read message from xbee

    data = Serial1.read();

    // parse message data

    if (data == 'A') {

      startfound = 1;

      midfound = 0;

      endfound = 0;

      message = "";

    }

    else if (data == 'B') {

      startfound = 0;

      midfound = 1;

      endfound = 0;

    }

    else if (data == 'C') {

      startfound = 0;

      midfound = 0;

      endfound = 1;

    }

    else if (startfound) {

      message = message + data;

    }

    else if (midfound) {

      if(data == '1')

        brake = 1;

      else

        brake = 0;

      message.toCharArray(intbuf, sizeof(intbuf));

      steeringAngle = atoi(intbuf);

    }  

    // flop external LED everytime message is recieved

    if ( pingPong == 0 ) {

      digitalWrite(4, LOW);

    } 

    else {

      digitalWrite(4, HIGH);

    }

    pingPong = 1 - pingPong;

  } // end receive message

  // brake if it has been greater than 3 seconds since we last got a message

  if( (millis() - timer) > 5000L ) {

    digitalWrite(8, 0);

    digitalWrite(5, HIGH);

    exit(1);

  }

  if((millis() - timer) > 2000L) {

    digitalWrite(12, HIGH);

  }

  else {

    digitalWrite(12, LOW);

  }

  // make brake LED light up if brakes should be down

  if( brake == 0 ) {

    digitalWrite(5, HIGH);

  } 

  else {

    digitalWrite(5, LOW);

  }

  // send parsed signal to brakes and servo

  digitalWrite(8, brake);

  // sets the servo position

  myservo.write(steeringAngle);

}